Interfacing A 7-Segment Display To An Arduino Uno

Last Updated: August 20, 2021
Originally Published: February 15, 2019

Skill Level: Intermediate

Table Of Contents

• Introduction
• What Is Needed
• Background Information
• Building The Circuit
• Writing The Sketch
• Running And Testing The System
• Summary

Introduction

This tutorial will teach you how to interface a 7-segment display to an Arduino Uno.

A basic understanding of electronics and programming is expected along with some familiarity with the Arduino platform. If you are new to the Arduino platform or would just like to refresh your knowledge, please see our Blink: Making An LED Blink On An Arduino Uno tutorial before proceeding with this one.

This tutorial will use a solderless breadboard to build a circuit from a schematic diagram. The All About Circuit’s Understanding Schematics, SparkFun’s How to Read a Schematic, Core Electronics’ How to Use Breadboards, and Science Buddies’ How to Use a Breadboard guides are good resources for learning how to translate a schematic to a breadboard.

The resources created for this tutorial are available on GitHub for your reference.

What Is Needed

• Linux, macOS, Or Windows Based Computer With A USB Port
• Arduino IDE
• Arduino Uno (R3 available on Arduino and SparkFun, WiFi Rev2 available on Arduino and SparkFun) With Compatible USB Cable
• Solderless Breadboard (available on Adafruit and SparkFun)
• Preformed Breadboard Jumper Wire Kit (available on SparkFun and CanaKit)
• 7 x Male-Male Jumper Wires (available on Adafruit and Arrow)
• 74LS47 BCD To 7-Segment Decoder/Driver Integrated Circuit (available on Arrow and Digi-Key)
• 7-Segment Display (available on SparkFun and Digi-Key)
• Momentary Push Button (available on Adafruit and SparkFun)
• 7 x 330 Ω Resistors (available on SparkFun and Amazon)

Background Information

I am using the Arduino Uno WiFi Rev2 development board connected to a macOS based computer with the desktop Arduino IDE. If you are using a different Arduino board or computer setup, the vast majority of this tutorial should still apply, however, some minor changes may be necessary.

In this tutorial, I will be connecting a common anode 7-segment display to an Arduino through a 74LS47 BCD To 7-Segment Decoder/Driver integrated circuit (IC). This chip decodes binary coded decimal (BCD), which is just basic binary numbers for the 0-9 decimal digits, into the individual LED segments of a 7-segment display. The 4 BCD inputs of the chip are denoted as A through D, while the individual LED segment outputs are denoted as a through g. See the 74LS47 datasheet for more information. While usage of the IC is not strictly necessary, it does allow us to use fewer Arduino GPIO pins and write a simpler program. If you prefer to use a common cathode display instead, replace the 74LS47 decoder IC with a 74LS48 chip and make sure to connect the common terminals of the display to ground instead of power.

If you need assistance with your particular setup, post a question in the comments section below and I, or someone else, can try to help you.

Building The Circuit

Before connecting any circuitry to your Arduino board, disconnect it from power and your computer. This avoids accidental damage during wiring.

Place the components and wire up the circuit on a breadboard according to the schematic diagram shown below.

I left the LT, BI, and RBI inputs of the 74LS47 IC disconnected as we will not be utilizing those testing and blanking features.

A 0.1 µF bypass capacitor was placed across the power pins of the 74LS47 IC in order to reduce any power supply noise that may be present in the system.

Note, you may come across other 7-segment display circuits using only one resistor at the common terminal(s), but using resistors across all the segments, as done here, ensures a constant level of brightness regardless of how many segments are lit.

The circuit should look similar to the one shown below once completed. Note, I used a two digit display (that I had available) in my circuit, but I only connected one digit.

Once the circuit is built, connect your Arduino to your computer with the USB cable.

Writing The Sketch

Open the Arduino IDE and create a new sketch named BCD7SegmentDisplay with the code shown below.

const uint8_t Button = 2;
const uint8_t BCD_A = 3;
const uint8_t BCD_B = 4;
const uint8_t BCD_C = 5;
const uint8_t BCD_D = 6;

const unsigned long DisplayPeriod = 1000;

void setup() {
   pinMode(Button, INPUT_PULLUP);
   pinMode(BCD_A, OUTPUT);
   pinMode(BCD_B, OUTPUT);
   pinMode(BCD_C, OUTPUT);
   pinMode(BCD_D, OUTPUT);
}

void loop() {
   static uint8_t count = 0;  // display count
   static unsigned long previousDisplayTime = 0;
   unsigned long currentTime = millis();

   if (digitalRead(Button) == LOW) count = 0;  // reset count if button pressed
   if (currentTime - previousDisplayTime >= DisplayPeriod) {  // check if time to update display
      displayWrite(count);  // update display
      count++;  // increase counter
      if (count == 10) count = 0;  // reset to 0 if count exceeds 9
      previousDisplayTime = currentTime;
   }
}

void displayWrite(uint8_t value) {
   digitalWrite(BCD_A, bitRead(value, 0));  // BCD LSB
   digitalWrite(BCD_B, bitRead(value, 1));
   digitalWrite(BCD_C, bitRead(value, 2));
   digitalWrite(BCD_D, bitRead(value, 3));  // BCD MSB
}

Let’s take a look at some of the more interesting parts of the code.

The BCD_A through BCD_D pins, defined on lines 2-5, represent the A through D BCD inputs of the 74LS47 chip, which itself subsequently drives the a through g segment inputs of the 7-segment display.

The DisplayPeriod, defined on line 7, sets the time between display updates in milliseconds. The value of 1000 means the display will be updated every second.

The pin mode of the button, defined on line 10, is specified as INPUT_PULLUP, which uses the internal pull-up resistor for the pin within the microprocessor on the Arduino board, instead of just INPUT since we did not use an external pull-up resistor in the circuit.

The loop() routine performs a variety of operations:

• It defines and keeps track of the count that is displayed on the 7-segment display and resets it back to 0 when the next value to be displayed reaches double digits.
• Checks if the reset button was pressed, and if so, resets the counter.
• Keeps track of the time when the display needs to be updated according the specified display period and calls the displayWrite() function when the display is ready to be updated.

The displayWrite() function utilizes the Arduino bitRead() function to write the appropriate binary coded decimal (BCD) values to the 74LS47 chip that then translates those values to drive the appropriate LED segments of the display. Speaking of bitRead(), this function just translates a number into its individual binary bits. For example bitRead(5, 0) will return 1 since the least significant bit in the number 5, 00000101 in binary, is 1. Likewise, bitRead(5, 1) will return 0.

If there is something that needs further explanation, please let me know in the comment section and I will try to answer your question.

Running And Testing The System

Now that our circuit is built and our software is written, it is time to run and test our display project.

Upload (Sketch > Upload) the sketch to the board and you should see the 7-segment display counting up from 0. When it reaches 9, it should reset back to 0. Press the button on the breadboard at any time and the display should reset back to 0 during the next display update cycle.

Before we end, now would be a good time to upload the BareMinimum sketch (Main Menu > File > Examples > 01.Basics > BareMinimum) to reset all pins back to their default states. This ensures no outputs are being driven when plugging in your board for your next project.

Summary

In this tutorial, we learned how to interface a common anode 7-segment display to an Arduino Uno using a 74LS47 BCD To 7-Segment Decoder/Driver integrated circuit.

The final source code and schematic used for this tutorial is located on GitHub.

Thank you for joining me along this journey and I hope you enjoyed the experience. Please feel free to share your thoughts in the comments section below.